快速掌握公式编写(3)

STICKLINE——画柱线，0实心柱，-1虚线空心柱，1实线空心柱。后面的输出会遮挡住前面的输出。

 

MA5:MA(C,5);

 

画柱线1:STICKLINE(C>O,C,O,2,0);

画柱线2:STICKLINE(C>O,H,L,0,0),COLORBLUE;

 

画柱线3:STICKLINE(C<O,H,L,1,1);

画柱线4:STICKLINE(C<O,C,O,3,-1);

 

MA10:MA(C,10),COLORGREEN;

 

DRAWLINE——绘制直线段，0不延长，1向右延长。PLOYLINE——绘制折线。

 

画直线:DRAWLINE(L=LLV(L,10),L,H=HHV(H,10),H,0);

画折线:PLOYLINE(H=HHV(H,30),H);

 

均线变色，DRAWNULL——返回无效值。nodraw——只输出数值、不输出线条，不影响公式坐标。LINETHICK0——只输出数值、不输出线条，在其它软件中不影响公式坐标，在通达信中影响公式坐标。

 

MA1:MA(C,5);

MA2:MA(C,10);

变色:IF(MA1>REF(MA1,1),MA1,DRAWNULL),LINETHICK2,COLORRED;

成交量:V,NODRAW;

 

MA1:MA(C,5);

MA2:MA(C,10);

变色:IF(MA1>MA2,MA1,DRAWNULL),LINETHICK2,COLORRED;

成交量:V,LINETHICK0;

 

Winner——获利盘，cost——成本分布情况。

 

获利盘:WINNER(C)*100;

成本分布:COST(80);

 

Zig——之字转向，1最高价、2最低价、3收盘价。PEAK——波峰价格，1最高价、2最低价、3收盘价。TROUGH——波谷价格，1最高价、2最低价、3收盘价。

 

之字转向:ZIG(3,10);

波峰:PEAK(3,10,1);

波谷:TROUGH(3,10,1);

 

波峰到现在的周期数——PEAKBARS，波谷到现在的周期数——TROUGHBARS。

 

波峰到现在周期:PEAKBARS(3,10,1);

波谷到现在周期:TROUGHBARS(3,10,1);

 

BACKSET——回设，马后炮。

 

MA10:MA(C,10);

回设:=BACKSET(C/REF(C,1)>1.09,2);

A:=IF(REF(回设,1)=0 AND 回设=1,1,0);

DRAWICON(A,L*0.98,1);

 

跨周期引用的公式也具有未来性质。

 

周J:"KDJ.J#WEEK";

周D:"KDJ.D#WEEK";

金叉:CROSS(周J,周D)*30;

 

还有一种作弊手法——将公式信号限制在有行情的时段发出。

 

另外一种作弊:O<REF(C,1) AND DATE=1080918;

 

建议暂时关闭本教程，把讲义中这一节的内容挨个复制到你自己的软件中，按照这一节开始时所讲的函数学习方法复习一遍。

要将自己的思路用公式去表达出来，首先是确定需要哪些数据，然后观察这些数据之间的关系，再按语句规则的要求用函数去定义观察到的关系。

 

{K线形态}

 

阴线:C<O;

阳线:C>O;

 

上涨:C>REF(C,1);

下跌:C<REF(C,1);

平盘:C=REF(C,1);

 

大阳线:C/REF(C,1)>1.05;

大阴线:C/REF(C,1)<0.95;

 

高开:O>REF(C,1);

低开:O<REF(C,1);

 

高开高走:O>REF(C,1) AND C>O;

高开低走:O>REF(C,1) AND C<O;

 

低开低走:O<REF(C,1) AND C<O;

低开高走:O<REF(C,1) AND C>O;

 

上跳空:L>REF(H,1);

下跳空:H<REF(L,1);

 

长上影:H/MAX(O,C)>1.03;

长下影:MIN(O,C)/L>1.03;

 

十字星:MAX(O,C)/MIN(O,C)<1.02 AND H/MAX(O,C)>1.01 AND MIN(O,C)/L>1.01;

 

正T字:O=C AND C=H AND L<H;

倒T字:O=C AND C=L AND H>L;

 

一字涨停:O=C AND C=H AND L=H AND C>REF(C,1);

一字跌停:O=C AND C=L AND L=H AND C<REF(C,1);

 

横盘:HHV(H,20)/LLV(L,20)<1.15;

 

    均线状况——金叉和死叉。

 

MA1:MA(C,5);

MA2:MA(C,10);

金叉:CROSS(MA1,MA2);

死叉:CROSS(MA2,MA1);

 

    均线上拐、下拐、将死未死。

 

MA1:MA(C,5);

MA2:MA(C,10);

上拐:=REF(MA1,1)<REF(MA1,2) AND MA1>REF(MA1,1);

下拐:=REF(MA1,1)>REF(MA1,2) AND MA1<REF(MA1,1);

将死未死:=COUNT(MA1>MA2,5)=5 AND 上拐;

DRAWICON(上拐,MA1*0.98,1);

DRAWICON(下拐,MA1*1.01,2);

DRAWICON(将死未死,MA1*0.96,11);

 

多头排列、空头排列。

 

MA1:MA(C,5);

MA2:MA(C,10);

MA3:MA(C,20);

多头排列:=MA1>MA2 AND MA2>MA3;

空头排列:=MA1<MA2 AND MA2<MA3;

STICKLINE(多头排列,MA1,MA3,0,0),COLORRED;

STICKLINE(空头排列,MA1,MA3,0,0),COLORGREEN;

 

    均线粘合、粘合一段时间。

 

MA1:MA(C,5);

MA2:MA(C,10);

MA3:MA(C,20);

粘合:=MAX(MAX(MA1,MA2),MA3)/MIN(MIN(MA1,MA2),MA3)<1.02;

粘合一段时间:=COUNT(粘合,10)=10;

STICKLINE(粘合,MAX(MAX(MA1,MA2),MIN(MIN(MA1,MA2),MA3)),MA3,1,0),COLORRED;

DRAWICON(粘合一段时间,MA3*0.98,1);

 

    三金叉。

 

DIF2:"ACD/">MACD.DIF";

DEA2:"MACD.DEA";

单金叉:CROSS(DIF2,DEA2);

三金叉:(单金叉 AND COUNT(单金叉,10)>=3)*2;

 

成交量状况——主要观察成交量之间、成交量与均量线之间以及换手率之间的关系。放量、历史天量。

 

放量1:V>REF(V,1)*2;

放量2:V>MA(V,60);

放量3:V*100/FINANCE(7)*100>8;

历史天量:V=HHV(V,0);

 

连续放量。

 

连续放量1:COUNT(V>REF(V,1),5)=5;

连续放量2:(COUNT(V>MA(V,60),5)=5)*2;

连续放量3:(COUNT(V*100/FINANCE(7)*100>8,5)=5)*3;

 

    缩量、历史地量。

 

缩量1:V<REF(V,1)*0.5;

缩量2:V<MA(V,60);

缩量3:V*100/FINANCE(7)*100<1;

历史地量:V=LLV(V,0);

 

    连续缩量。

 

连续缩量1:COUNT(V<REF(V,1),5)=5;

连续缩量2:(COUNT(V<MA(V,60),5)=5)*2;

连续缩量3:(COUNT(V*100/FINANCE(7)*100<1,5)=5)*3;

 

筹码低位密集。

 

筹码密集:=(WINNER(C*1.1)-WINNER(C*0.9))*100>50;

相对低位:=(C-COST(0.01))/(COST(99.99)-COST(0.01))*100<10;

低位密集:筹码密集 AND 相对低位;

 

第05节  公式转换

 

技术指标转换为条件选股公式：第一步，确定我们想要的信号；第二步，从下到上寻找信号的关联语句；第三步，删除无用语句；第四步，将信号以外的语句变成中间语句，并删除修饰美化函数；第五步，将公式建立在条件选股类别。

 

{改造前}

LC:=REF(C,1);

RSI1:SMA(MAX(C-LC,0),6,1)/SMA(ABS(C-LC),6,1)*100;

RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;

K:SMA(RSV,3,1);

D:SMA(K,3,1);

J:3*K-2*D,LINETHICK2;

MJ:=CROSS(J,D);

MC:=CROSS(D,J);

DRAWICON(MJ,J,1);

DRAWICON(MC,J,2);

 

{改造后}

RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;

K:=SMA(RSV,3,1);

D:=SMA(K,3,1);

J:=3*K-2*D;

CROSS(J,D);

 

上一页  [1] [2] [3] [4] 下一页